MS PowerPoint

These are MS PowerPoint-specific VBA tips:

Insert Scpecial Characters — for no rational reason, PowerPoint doesn't offer any way to insert a non-breaking space, non-breaking space hyphen, or optional hy. The following code does that insertion for a space. This code, and also code to insert a non-breaking or optional hyphen is offered as a PowerPoint 2007 Add-In.
```
Sub InsertNonBreakSpace()
    On Error Resume Next
    
    ' Check that we're actually in text insertion mode.  If we are, then go ahead
    ' and insert the non-breaking space character.
    If ppSelectionText = ActiveWindow.Selection.Type Then
        ActiveWindow.Selection.TextRange.Characters.Text = Chr$(160)
    End If
End Sub
```

Delete Empty Text Frames — sometimes after working on a presentation, you're left with some empty text frames that you have forgotten to clean-up, or the slides are cluttered with a lot of empty placeholder frames left over from the master template pages. In either case, this code will remove any empty text frames or placeholder frames from a presentation file. This code is also offered as a PowerPoint 2007 Add-In. Note the add-in checks for empty text frames that have a fill colour and doesn't delete them.

Sub DeleteEmptyFrames()
    Dim aSlide As Slide

    ' Visit each slide in the file.
    For Each aSlide In ActivePresentation.Slides
        Dim i As Integer
        ' On each slide, count down through the shapes to avoid encountering
        ' VBA's idiotic object model that can't handle objects being deleted
        ' from a set.
        For i = aSlide.Shapes.Count To 1 Step -1
            ' If the shape IS a text box and DOES NOT have text
            With aSlide.Shapes(i)
                If (.Type = msoTextBox) And Not .TextFrame.HasText Then
                    ' Check for a native textframe that is empty; if so, delete.
                    .Delete
                ElseIf (.Type = msoPlaceholder) And .HasTextFrame Then
                    ' Check for a placeholder containing an empty textframe; if so, delete.
                    If Not .TextFrame.HasText Then
                        .Delete
                    End If
                End If
            End With
        Next
    Next
End Sub

Other Resources

See the page that linked to this one for other VBA resources I have found helpful.